sed命令解析

处理文件的工具sed


Stream EDitor, 行编辑器
一次只读一行，只处理一行，不对源文件做处理，至输出到屏幕上模式空间

sed是一种流编辑器，它一次处理一行内容。处理时，把当前处理的行存储在临时缓冲区中，称为“模式空间”（pattern space），
接着用sed命令处理缓冲区中的内容，处理完成后，把缓冲区的内容送往屏幕。接着处理下一行，这样不断重复，直到文件末尾。
文件内容并没有改变，除非你使用重定向存储输出。Sed主要用来自动编辑一个或多个文件,简化对文件的反复操作,编写转换程序等

用法：
    sed[option]... 'script' inputfile...

常用选项：
    -n: 静默模式，不输出模式空间中的内容;
    -n, --quiet, --silent
          suppress automatic printing of pattern space
    -r: 扩展的正则表达式
    -r, --regexp-extended
          use extended regular expressions in the script.     
    -f /path/to/sed_script_file: 指定sed脚本文件
    -f script-file, --file=script-file
          add the contents of script-file to the commands to be executed
    -e 'script' -e 'script': 指定多个编辑指令
    -e script, --expression=script
          add the script to the commands to be executed
    -i: 直接编辑原文件
          edit files in place

script:
    '地址命令'

编辑命令：
    d: 删除
    p: 打印
    i \text: \n 换行符   行前面插入文本
    a \text: \n 换行符   行下面插入文本
    r /path/to/somefile: 在指定位置把另外一个文件的内容插入进来
    w /path/to/somefile：将符合条件的所有行保存至指定的文件中
    =：显示符合条件的行的行号
    s///: 查找条件可以使用模式，但要替换的内容不行
        ///可以替换为@@@或者###或者$$$
        g：行内全局替换
        p：显示替换成功的行
        w /path/to/somefile：将替换成功的行保存至文件中
    !：模式空间中匹配行取反处理

地址定界
(1) 不给地址：对全文进行处理
(2) 单地址：
    #: 指定的行
    /pattern/：被此处模式所能够匹配到的每一行
(3) 地址范围：
    #,#
    #,+#
    /pat1/,/pat2/
    #,/pat1/
(4) ~：步进
    1~2 奇数行
    2~2 偶数行
    
用法
    #sed [options] 'addr1[,addr2]编辑命令' FILE ...
    #sed [options] “addr1[,addr2]编辑命令” FILE ...

[root@centos7 tmp]# cat f1 /etc/passwd | head -5
     1	root:x:0:0:Sxj,001,002,003:/root:/bin/bash
     2	bin:x:1:1:bin:/bin:/sbin/nologin
     3	daemon:x:2:2:daemon:/sbin:/sbin/nologin
     4	adm:x:3:4:adm:/var/adm:/sbin/nologin
     5	lp:x:4:7:lp:/var/spool/lpd:/sbin/nologin

[root@centos7 tmp]# sed '2p' f1 | head -5
###2p  即打印第二行
     1	root:x:0:0:Sxj,001,002,003:/root:/bin/bash
     2	bin:x:1:1:bin:/bin:/sbin/nologin
     2	bin:x:1:1:bin:/bin:/sbin/nologin
     3	daemon:x:2:2:daemon:/sbin:/sbin/nologin
     4	adm:x:3:4:adm:/var/adm:/sbin/nologin

[root@centos7 tmp]# sed -n '2p' f1 
###-n 不输出模式空间中的内容；注意看和上面的区别
     2	bin:x:1:1:bin:/bin:/sbin/nologin

[root@centos7 tmp]# sed -n '1,4p' f1 
     1	root:x:0:0:Sxj,001,002,003:/root:/bin/bash
     2	bin:x:1:1:bin:/bin:/sbin/nologin
     3	daemon:x:2:2:daemon:/sbin:/sbin/nologin
     4	adm:x:3:4:adm:/var/adm:/sbin/nologin

[root@centos7 tmp]# sed -n '/root/p' f1
###包含root字符串的行输出出来
     1	root:x:0:0:Sxj,001,002,003:/root:/bin/bash
    10	operator:x:11:0:operator:/root:/sbin/nologin
    49	rooter:x:0:5009::/home/rooter:/bin/bash

[root@centos7 tmp]# cat -n f2
     1	1
     2	
     3	2
     4	
     5	
     6	3
     7	
  
[root@centos7 tmp]# sed -n '/^$/=' f2
###输出空行的行号 结合上面的cat命令可以看出效果
2
4
5
7
[root@centos7 tmp]# sed -n -e '/^$/p' -e '/^$/=' f2
###-e指定多个编辑命令

2

4

5

7

[root@centos7 tmp]# sed '/^$/d' f2
1
2
3

[root@centos7 tmp]# sed '1,10d' f1 | head -5
    11	games:x:12:100:games:/usr/games:/sbin/nologin
    12	ftp:x:14:50:FTP User:/var/ftp:/sbin/nologin
    13	nobody:x:99:99:Nobody:/:/sbin/nologin
    14	systemd-bus-proxy:x:999:998:systemd Bus Proxy:/:/sbin/nologin
    15	systemd-network:x:998:997:systemd Network Management:/:/sbin/nologin

[root@centos7 tmp]# sed -n 's/root/&superman/p' /etc/passwd
rootsuperman:x:0:0:Sxj,001,002,003:/root:/bin/bash
operator:x:11:0:operator:/rootsuperman:/sbin/nologin
rootsupermaner:x:0:5009::/home/rooter:/bin/bash

[root@centos7 tmp]# sed -i.bak 's/root/superman/g' f1
###会直接修改文件f1 同时生成备份文件f1.bak  f1.bak为修改前的内容

[root@centos7 tmp]# cat /etc/fstab | sed  -e 's@UUID@ABC@g' -e 's@ABC@DEF@g'
###

DEF=174a1f45-937a-4844-9650-27550836880d /                       ext4    defaults        1 1
DEF=a9778fb4-3adb-471b-96ff-571d2325ee3c /boot                   ext4    defaults        1 2
DEF=fb15ae62-3c30-4cbb-9d4e-a0e3e2531e8c /testdir                ext4    defaults        1 2
DEF=ba38f744-eb07-4306-b0a0-9b58a9ba81f2 swap                    swap    defaults        0 0

[root@centos7 tmp]# cat /etc/fstab | sed  -e 's@UUID@ABC@g' -e 's@UUID@DEF@g'
###和上一个做比较，可以看出第二个-e后的编辑命令是处理第一个-e处理之后的结果

ABC=174a1f45-937a-4844-9650-27550836880d /                       ext4    defaults        1 1
ABC=a9778fb4-3adb-471b-96ff-571d2325ee3c /boot                   ext4    defaults        1 2
ABC=fb15ae62-3c30-4cbb-9d4e-a0e3e2531e8c /testdir                ext4    defaults        1 2
ABC=ba38f744-eb07-4306-b0a0-9b58a9ba81f2 swap                    swap    defaults        0 0

高级编辑命令：
    h: 把模式空间中的内容覆盖至保持空间中
    H：把模式空间中的内容追加至保持空间中
    g: 从保持空间取出数据覆盖至模式空间
    G：从保持空间取出内容追加至模式空间
    x: 把模式空间中的内容与保持空间中的内容进行互换
    n: 读取匹配到的行的下一行覆盖至模式空间
    N：追加匹配到的行的下一行至模式空间
    d: 删除模式空间中的行
    D：删除当前模式空间开端至\n的内容（不在传至标准输出），
       放弃之后的命令，但是对剩余模式空间重新执行sed

下面用几个实例来说明sed的高级用法：

# sed -n 'n;p' /etc/fstab 显示偶数行
# sed '1!G;h;$!d' FILE 逆序显示文件内容
# sed '$!d' FILE  取出最后一行
# sed '$!N;$!D' FILE  取出文件后两行；
# sed '/^$/d;G' FILE 删除原有的所有空白行，而后为所有非空白行添加一个空白行
# sed 'n;d' FILE 显示奇数行
# sed 'G' FILE 在原有的每行后方添加一个空白行